%%HP: T(3)A(D)F(.);
\<< 'BP' VTYPE
  IF -1. ==
  THEN { 600. 1156.
12.89 12.22 3. 36. }
'BP' STO
  END
"AISC BASE PLATE DESIGN"
{ { "P="
"COLUMN LOAD, KIPS"
0. } { "A2="
"Area of Concrete Support, sq.in."
0. } { "d="
"Column depth, in."
0. } { "bf="
"Column flange width, in."
0. } { "fc\180="
"Concrete Strength, ksi"
0. } { "Fy="
"Yield Stress, ksi"
0. } } { 2. 0. } BP
BP INFORM ESC 'BP'
STO BP OBJ\-> DROP \-> P
A2 \<-d \<-bf fc\180 \<-Fy
  \<< P .35 fc\180 * / SQ
A2 / P .7 fc\180 * / MAX
\<-bf \<-d * MAX DUP \v/ \<-d
MAX CEIL DUP2 / \<-bf
MAX CEIL 2. \->LIST \->
A1 DM
    \<<
      DO CLEAR
"GET PLATE DIMENSIONS"
{ { "N="
"PLATE HEIGHT, IN."
0. } { "B="
"PLATE WIDTH, IN." 0.
} } { 2. 0. } DM DM
INFORM ESC OBJ\-> DROP
DUP2 * A1 \>= OVER \<-bf
\>= 4. PICK \<-d \>=
      UNTIL AND AND
      END
    \>> DUP2 * DUP P
SWAP / SWAP A2 SWAP /
\v/ fc\180 * .35 * .7 fc\180
* MIN \-> N B fp Fp
    \<< "fp = " fp \->STR
+ " ksi
Fp = " + Fp
\->STR + " ksi" + SCRN
4. fp \<-d \<-bf * * * \<-d
\<-bf + SQ Fp * / .64
MIN DUP 1. SWAP - \v/
1. SWAP - 2. * SWAP \v/
/ \<-d \<-bf * \v/ 4. / * N
\<-d .95 * - 2. / B \<-bf
.8 * - 2. / 3. DUPN
"    n = " SWAP \->STR
+ " in.
    m = " +
SWAP \->STR +
" in.
  \Gln\180 = " +
SWAP \->STR +
" in.
t-req = " + 4.
ROLLD MAX MAX 2. * fp
\<-Fy / \v/ * \->STR +
" in." + SCRN
    \>>
  \>>
\>>