%%HP: T(3)A(D)F(.);
\<< 'WDC' VTYPE
  IF -1. ==
  THEN { { 1843.75
640. 900. 360. 810.
0. } { 18. 6.5 3.25
.2 4000. 60000. } }
'WDC' STO
  END "WALL LOADING"
{ { "P_DL:"
"LOAD @ TOP, PLF" 0.
} { "P_LL:"
"LOAD @ TOP, PLF" 0.
} { "M_DL:"
"MOMENT @ TOP, FT-LB/FT"
0. } { "M_LL:"
"MOMENT @ TOP, FT-LB/FT"
0. } { "M:"
"LAT. LOAD MOMENT, FT-LB/FT"
0. } { "WIND?"
"WIND-0, SEISMIC-1"
0. } } { 2. 0. }
'WDC' 1. GET DUP
INFORM ESC 'WDC' 1.
ROT PUT
"WALL DESIGN CRITERIA"
{ { "LC:"
"HEIGHT OF WALL, FT"
0. } { "T:"
"WALL THICKNESS, INCHES"
0. } { "D:"
"DEPTH TO REINF STEEL, INCHES"
0. } { "AS:"
"AREA REINF STEEL, IN\178/FT"
0. } { "fc\180:"
"Concrete Strength, psi"
0. } { "Fy:"
"Steel Strength, psi"
0. } } { 2. 0. }
'WDC' 2. GET DUP
INFORM ESC 'WDC' 2.
ROT PUT 'WDC' 1. GET
OBJ\-> DROP 'WDC' 2.
GET OBJ\-> DROP \-> \<-Pdl
\<-Pll \<-Mdl \<-Mll \<-M \<-W
\<-lc \<-t \<-d \<-As \<-f\180c
\<-fy
  \<< \<-f\180c 1000. / \-> fc
'IFTE(fc\<=4.,.85,IFTE(
fc<8.,.85-.05*(fc-4.)
,.65))' 87000. DUP
\<-fy + / \<-f\180c \<-fy / *
OVER .85 * * \<-As \<-d
12. * / \<-t 3. ^ \<-f\180c
\v/ OVER * \<-t / 1.2 /
\<-lc SQ OVER * 3. *
950. / \<-f\180c \v/ / 3.
PICK / \-> \<-\Gb1 \Grb \Gr \<-Ig
\<-Mcr \<-\GDcr
    \<< " \Gb1= " \<-\Gb1
\->STR + "
 \Grb= " + 4.
FIX \Grb \->STR +
"
  \Gr= " + \Gr \->STR +
"
 Ig= " + 2. FIX \<-Ig
\->STR + " in^4
Mcr= "
+ \<-Mcr \->STR +
" ft-lb
\GDcr= " + \<-\GDcr
\->STR + " in" + SCRN
      IF '\Gr>.6*\Grb'
      THEN
"\Gr > 0.6\Grb
NO GOOD!"
MSGBOX
      END 1. SF CKCS
1. CF CKCS
    \>>
  \>>
\>>